//	たんしおスクリプト	Ver0.04版対応
//	2010/05/27
//	このスクリプトの仕様は大幅に変わる可能性があります！
//	使用される方は、仕様変更を覚悟してご利用ください！


//	[Init] ← 読み込み中に呼ばれるラベル
[Init]

SetTitle( "ドリームキャバ" ) ;

//--- 定義 -----------------------------------------------------------
int			IMG_TITLE    = 0 ;
int			IMG_BG       = 1 ;
int			IMG_BG2      = 2 ;
int			IMG_BG3      = 3 ;
int			IMG_BG_BLACK = 4 ;
int			IMG_CHARA    = 5 ;
int			IMG_CHARA2   = 6 ;
int			IMG_SCROLL   = 7 ;
int			IMG_PICT     = 8 ;
int			IMG_STAFF    = 9 ;

int			SE_START     = 0 ;
int			SE_SELECT    = 1 ;
int			SE_BGM       = 2 ;


//●●● 画像の読み込み ●●●●●●●●●●●●●●●
//	LoadImage( 画像番号, ファイル名 ) ;
LoadImage(  IMG_TITLE,    "muri08/title.png" ) ;
LoadImage(  IMG_BG,       "muri08/bg.jpg" ) ;
LoadImage(  IMG_BG2,      "muri08/bg2.jpg" ) ;
LoadImage(  IMG_BG3,      "muri08/bg3.jpg" ) ;
LoadImage(  IMG_BG_BLACK, "muri08/bg_black.gif" ) ;
LoadImage(  IMG_CHARA,    "muri08/chara.png" ) ;
LoadImage(  IMG_CHARA2,   "muri08/chara2.png" ) ;
LoadImage(  IMG_SCROLL,   "muri08/scroll.gif" ) ;
LoadImage(  IMG_PICT,     "muri08/picture.png" ) ;
LoadImage(  IMG_STAFF,    "muri08/staffroll.png" ) ;

End() ;	//	初期化終了(Ver0.04以降はこれを記述してください)


//●●● タイトルの設定 ●●●●●●●●●●●●●●●
[Start]
DelSprite( _ALL, 0 ) ;

//	タイトル画面をスプライトとして表示
//	Sprite( スプライト番号, 画像番号, アラインモード, Ｘ, Ｙ, プライオリティ, 表示されるまでの時間 ) ;
//	アラインに「_ALIGN_CENTER」を指定すると、画面中央に表示
Sprite( 0, IMG_TITLE, _ALIGN_CENTER,  0,   0, _PRIO_NORMAL, 0 ) ;

//	背景設定
//	BackGround( 画像番号, スクロールX, スクロールY ) ;
BackGround( IMG_SCROLL, -1, 1 ) ;

//	フェードインして画面表示
//	FadeIn( フォード時間 ) ;
FadeIn( 30 ) ;
Wait( 30 ) ;

//	キー入力待ち(クリックされるまでここで停止)
WaitKey( _INPUT_MOUSE ) ;
PlaySound( SE_START ) ;

//	フェードアウトしてタイトル終了
FadeOut( 30 ) ;
Wait( 30 ) ;
DelSprite( _ALL, 0 ) ;
BackGround( IMG_BG, 0, 0 ) ;
PlayBGM( SE_BGM ) ;

//●●● フェードインしてゲーム開始 ●●●●●●●●●
FadeIn( 30 ) ;
Wait( 30 ) ;

//	Sprite( スプライト番号, 画像番号, アラインモード, Ｘ, Ｙ, プライオリティ, 表示されるまでの時間 ) ;
Sprite( 1, IMG_CHARA, _ALIGN_BOTTOM, 100, 0, _PRIO_NORMAL, 30 ) ;

//	メッセージウィンドウを開く
Wait( 30 ) ;
OpenWindow( _WIN_MESSAGE ) ;

//	メッセージ中の「@S」 ▼を表示して入力待ちします
//	　　　　　　　「@C」 表示されているメッセージを全て消します

//−−−−−−−−メッセージはここまで■
_M_START_
受付「ドリームキャバへようこそ。
　　　ここは、ピュアな心の持ち主だけが
　　　入店できる大人の社交場です。@S@C
アナタはピュアな心をお持ちですか？
_M_END_

//−−−−−−−−メッセージはここまで■
Select( "[Sel_0001]Ａ．はい", "[Sel_0002]Ｂ．いいえ" ) ;

//●●●●●●●●●●●●●●●●●●●●●●●●●●●●●●●●●●

//--- いいえ -----------------------------------------
[Sel_0002]
PlaySound( SE_SELECT ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
@C受付「申し訳ございません。
　　　当店はピュアな心をお持ちの方しか
　　　入店することは出来ません。@S
　　　またのご来店を心よりお待ちして
　　　おります。@S
_M_END_

Jump( "[End]" ) ;


//--- はい -------------------------------------------
[Sel_0001]
PlaySound( SE_SELECT ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
@C受付「それでは、どうぞお入りください。@S@C
_M_END_

CloseWindow( _WIN_MESSAGE ) ;
FadeOut( 30 ) ;
Wait( 30 ) ;
DelSprite( _ALL, 0 ) ;
BackGround( IMG_BG2, 0, 0 ) ;
FadeIn( 30 ) ;
Wait( 30 ) ;

//	Sprite( スプライト番号, 画像番号, アラインモード, Ｘ, Ｙ, プライオリティ, 表示されるまでの時間 ) ;
Sprite( 1, IMG_CHARA2, _ALIGN_BOTTOM, 300, 0, _PRIO_NORMAL, 30 ) ;

//	メッセージウィンドウを開く
Wait( 30 ) ;
OpenWindow( _WIN_MESSAGE ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
@Cフグ美「はじめまして、フグ美っていいます。
　　　　ピュアな方なんですよね？@S
　　　　ピュアだったら、外見なんて気に
　　　　しないですよね？@S@C
_M_END_

//●●● 外見 ●●●●●●●●●●●●●●●●●●●●●●●●●●●●

Select( "[Sel_1001]Ａ．ピュアだから外見は気にしない", "[Sel_1002]Ｂ．いいえ" ) ;


//--- いいえ -----------------------------------------
[Sel_1002]
PlaySound( SE_SELECT ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
@Cフグ美「ヒドイ！
　　　　ピュアだなんてウソだったんですね！
　　　　この店から出て行ってください！@S@C
_M_END_

Jump( "[OutEnd]" ) ;


//--- 気にしない -------------------------------------
[Sel_1001]
PlaySound( SE_SELECT ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
@Cフグ美「良かったっ！
　　　　そうですよね、ピュアな人だったら
　　　　外見を気にするはずないですよね！@S
　　　　まずは何か飲み物を注文なさって
　　　　くださいね。@S@C
_M_END_

//●●● 飲み物 ●●●●●●●●●●●●●●●●●●●●●●●●●●●

Select( "[Sel_2001]Ａ．ビール", "[Sel_2002]Ｂ．ドクターペッパー", "[Sel_2003]Ｃ．シャンパン" ) ;


//--- シャンパン -------------------------------------
[Sel_2003]
PlaySound( SE_SELECT ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
@Cフグ美「ピュアな人はシャンパンなんて
　　　　飲みません！@S
　　　　ピュアだなんてウソだったんですね！
　　　　この店から出て行ってください！@S@C
_M_END_

Jump( "[OutEnd]" ) ;


//--- ビール -----------------------------------------
[Sel_2001]
PlaySound( SE_SELECT ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
@Cフグ美「ピュアなのにビール飲むんですか？
　　　　ちょっと変わってますね。@S
_M_END_

Jump( "[Jump_2000]" ) ;


//--- ドクターペッパー -------------------------------
[Sel_2002]
PlaySound( SE_SELECT ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
@Cフグ美「やっぱりピュアだったら
　　　　ドクターペッパーですよね！@S
_M_END_

Jump( "[Jump_2000]" ) ;


//●●● 飲み物選んだ後 ●●●●●●●●●●●●●●●●●●●●●●●
[Jump_2000]

_M_START_
　　　　かんぱーい！@S@C
（何か話をしようかな？）
_M_END_

Select( "[Sel_3001]Ａ．フグ美ちゃんの血液型", "[Sel_3002]Ｂ．フグ美ちゃんのこと", "[Sel_3003]Ｃ．フグ美ちゃんの好きなお酒" ) ;

//--- 血液型 -----------------------------------------
[Sel_3001]
PlaySound( SE_SELECT ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
@Cフグ美「どうしてそんなこと聞くんですか？@S
　　　　ひどい、魚なんてみんなＡ型なのに、
　　　　わざわざ血液型を聞くなんて！@S
　　　　私のこと、魚だと思ってバカに
　　　　してません？@S
　　　　とてもピュアな人とは思えません！
　　　　悲しいです、もう帰ってください！@S@C
_M_END_

Jump( "[OutEnd]" ) ;

//--- 好きなお酒 -------------------------------------
[Sel_3003]
PlaySound( SE_SELECT ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
@Cフグ美「やっぱり日本酒ですね。@S
　　　　フグのヒレを炙って日本酒に入れて、
　　　　美味しいヒレ酒になりますしね。@S
　　　　・・・・・・・・・・・・・・・。@S
　　　　ひどいっ！
　　　　私のこと干物にして炙って、ヒレ酒
　　　　にするつもりだったんですね！@S
　　　　あなたのことが信じられません。
　　　　悲しいです、もう帰ってください！@S@C
_M_END_

Jump( "[OutEnd]" ) ;


//--- こと -------------------------------------------
[Sel_3002]
PlaySound( SE_SELECT ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
@Cフグ美「私、太平洋の出身なんですよ。
　　　　陸に上がってから、まだ１ヶ月
　　　　なんですけど。@S@C
あの、国籍とか人種って気にされます？
_M_END_

//●●● 国籍 ●●●●●●●●●●●●●●●●●●●●●●●●●●●●

Select( "[Sel_4001]Ａ．ピュアだから気にしない", "[Sel_4002]Ｂ．いいえ" ) ;

//--- 気にする ---------------------------------------
[Sel_4002]
PlaySound( SE_SELECT ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
@Cフグ美「ひどい！
　　　　本当にピュアな人だったら人種差別
　　　　なんてするはずないのに！@S
　　　　悲しいです、もう帰ってください！@S@C
_M_END_

Jump( "[OutEnd]" ) ;


//--- 気にしない -------------------------------------
[Sel_4001]
PlaySound( SE_SELECT ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
@Cフグ美「良かったぁ！
　　　　そうですよね、ピュアな人はそんな
　　　　こと気にするはずないですよね。@S
　　　　海底の魚人が日本で働くのって、
　　　　なかなか大変なんですよ。@S
　　　　そうそう、絵画に興味あります？
　　　　私の故郷の画家の絵なんですけど。@S
_M_END_

//	Sprite( スプライト番号, 画像番号, アラインモード, Ｘ, Ｙ, プライオリティ, 表示されるまでの時間 ) ;
Sprite( 2, IMG_PICT, _ALIGN_CENTER, 0, -60, _PRIO_NORMAL, 30 ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
　　　　どうです？
　　　　素晴らしい絵だと思いませんか？@S
　　　　ピュアな心を持っていたら、きっと
　　　　この絵の素晴らしさが分かると
　　　　思います。@S@C
_M_END_

Select( "[Sel_5001]Ａ．ピュアだから良さが分かる", "[Sel_5002]Ｂ．素晴らしくない" ) ;

//--- 分からない -------------------------------------
[Sel_5002]
PlaySound( SE_SELECT ) ;

DelSprite( 2, 30 ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
@Cフグ美「ひどいっ！
　　　　私のこと騙したんですねっ！@S
　　　　全然ピュアな心を持ってないじゃ
　　　　ないですかっ！@S
　　　　悲しいです、もう帰ってください！@S
_M_END_

Jump( "[OutEnd]" ) ;

//--- 分かる -----------------------------------------
[Sel_5001]
PlaySound( SE_SELECT ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
@Cフグ美「ですよね！
　　　　ピュアな心の人なら、絶対にこの絵
　　　　の良さが分かるって信じてました！@S
　　　　この絵、３００万円なんですけど、
　　　　もちろん買いますよね？
　　　　ピュアなんですよね？@S@C
_M_END_

Select( "[Sel_6001]Ａ．ピュアだから買う", "[Sel_5002]Ｂ．買わない" ) ;

//--- 買う -------------------------------------------
[Sel_6001]
PlaySound( SE_SELECT ) ;

DelSprite( 2, 30 ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
@Cフグ美「お買い上げありがとうございます！
　　　　あなたがピュアな心の持ち主で
　　　　良かったです！@S
　　　　今日は楽しかったです。
　　　　また遊びに来てくださいね。
　　　　待ってます！@S
_M_END_

CloseWindow( _WIN_MESSAGE ) ;

//--- 表へ -----------------------------------------------------------
FadeOut( 30 ) ;
Wait( 30 ) ;
DelSprite( _ALL, 0 ) ;
BackGround( IMG_BG, 0, 0 ) ;
FadeIn( 30 ) ;
Wait( 30 ) ;

//	Sprite( スプライト番号, 画像番号, アラインモード, Ｘ, Ｙ, プライオリティ, 表示されるまでの時間 ) ;
Sprite( 1, IMG_CHARA, _ALIGN_BOTTOM, 280, 0, _PRIO_NORMAL, 30 ) ;

OpenWindow( _WIN_MESSAGE ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
受付「飲食代と絵画代、合わせて
　　　３２０万円です。@S
　　　どうされました？
　　　まさか持ち合わせがないんですか？@S
　　　お客さん、きちんと支払って
　　　いただかないと困ります。@S
　　　お金がないというのなら仕方がない
　　　ですね。
　　　奥へ入ってもらえますか？@S
_M_END_

CloseWindow( _WIN_MESSAGE ) ;

//--- 中へ -----------------------------------------------------------
FadeOut( 30 ) ;
Wait( 30 ) ;
DelSprite( _ALL, 0 ) ;
BackGround( IMG_BG2, 0, 0 ) ;
FadeIn( 30 ) ;
Wait( 30 ) ;

//	Sprite( スプライト番号, 画像番号, アラインモード, Ｘ, Ｙ, プライオリティ, 表示されるまでの時間 ) ;
Sprite( 1, IMG_CHARA2, _ALIGN_BOTTOM, 300, 0, _PRIO_NORMAL, 30 ) ;

OpenWindow( _WIN_MESSAGE ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
フグ美「この婚姻届に判を押して
　　　　もらえますか？@S
　　　　故郷では両親と兄弟が私の仕送り
　　　　を待っています。@S
　　　　魚人が日本で働き続けるには、
　　　　こうする他にないんです。@S
　　　　ピュアな心を持っていたら、判を
　　　　押せますよね？@S@C
_M_END_

Select( "[Sel_7001]Ａ．ピュアだから判を押す", "[Sel_7002]Ｂ．押さない" ) ;

//--- 押さない ---------------------------------------
[Sel_7002]
PlaySound( SE_SELECT ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
@Cフグ美「金も払えない、判も押さない、
　　　　そんなワガママが通るとでも
　　　　思ってるんですか？@S
　　　　仕方がないですね、地下王国
　　　　で一生働き続けてもらいます。@S
_M_END_

CloseWindow( _WIN_MESSAGE ) ;

//--- 地底へ ---------------------------------------------------------
StopBGM( 30 ) ;
FadeOut( 30 ) ;
Wait( 30 ) ;
DelSprite( _ALL, 0 ) ;
BackGround( IMG_BG3, 0, 0 ) ;
FadeIn( 30 ) ;
Wait( 30 ) ;

OpenWindow( _WIN_MESSAGE ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
そして、この地下王国で一生奴隷として
生きていくのでした。
　　　　　　　　　　　　　（おしまい）@S
_M_END_

FadeOut( 30 ) ;
Wait( 30 ) ;

CloseWindow( _WIN_MESSAGE ) ;
Jump( "[Start]" ) ;


//--- 押す -------------------------------------------
[Sel_7001]
PlaySound( SE_SELECT ) ;

CloseWindow( _WIN_MESSAGE ) ;

//--- 表へ -------------------------------------------
FadeOut( 30 ) ;
Wait( 30 ) ;
DelSprite( _ALL, 0 ) ;
BackGround( IMG_BG, 0, 0 ) ;
FadeIn( 30 ) ;
Wait( 30 ) ;

//	Sprite( スプライト番号, 画像番号, アラインモード, Ｘ, Ｙ, プライオリティ, 表示されるまでの時間 ) ;
Sprite( 1, IMG_CHARA, _ALIGN_BOTTOM, 280, 0, _PRIO_NORMAL, 30 ) ;

OpenWindow( _WIN_MESSAGE ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
受付「ご結婚おめでとうございまーす！
　　　末永く幸せに！@S
　　　代金の３２０万は３５年ローンを
　　　組んでおきましたので、のんびり
　　　お支払いくださいね！@S
_M_END_

//--- 暗転 -------------------------------------------
CloseWindow( _WIN_MESSAGE ) ;
FadeOut( 30 ) ;
Wait( 30 ) ;
DelSprite( _ALL, 0 ) ;
BackGround( IMG_BG_BLACK, 0, 0 ) ;
FadeIn( 30 ) ;
Wait( 30 ) ;

OpenWindow( _WIN_MESSAGE ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
受付「本当にピュアな心を持っていたら、
　　　こんな店に来るわけないのにねｗ@S
_M_END_

Jump( "[StaffRoll]" ) ;


//--- タイトル画面に戻る -----------------------------
[End]

StopBGM( 30 ) ;
FadeOut( 30 ) ;
Wait( 30 ) ;

CloseWindow( _WIN_MESSAGE ) ;
Jump( "[Start]" ) ;

//--- 外に出てタイトル画面に戻る ---------------------
[OutEnd]

StopBGM( 30 ) ;
CloseWindow( _WIN_MESSAGE ) ;
FadeOut( 30 ) ;
Wait( 30 ) ;
DelSprite( _ALL, 0 ) ;
BackGround( IMG_BG, 0, 0 ) ;
FadeIn( 30 ) ;
Wait( 60 ) ;
FadeOut( 30 ) ;
Wait( 30 ) ;

Jump( "[Start]" ) ;


//--- スタッフロール ---------------------------------
[StaffRoll]

CloseWindow( _WIN_MESSAGE ) ;
FadeOut( 30 ) ;
Wait( 30 ) ;
DelSprite( _ALL, 0 ) ;

//	背景設定
//	BackGround( 画像番号, スクロールX, スクロールY ) ;
BackGround( IMG_STAFF, 0, 1 ) ;

FadeIn( 30 ) ;
Wait( 1800 ) ;

StopBGM( 30 ) ;
FadeOut( 30 ) ;
Wait( 30 ) ;

Jump( "[Start]" ) ;