//	たんしおスクリプト	Ver0.07版対応
//	2010/06/08


//	[Init] ← 読み込み中に呼ばれるラベル
[Init]

SetTitle( "たんしおツクールサンプル" ) ;

//●●● 画像の読み込み ●●●●●●●●●●●●●●●
//	LoadImage( 画像番号, ファイル名 ) ;
LoadImage(  0, "image/akari.gif" ) ;		//	０：あかりの画像
LoadImage(  1, "image/title.gif" ) ;		//	１：タイトル画面
LoadImage(  2, "image/wallpaper.png" ) ;	//	２：背景
LoadImage(  3, "image/bg.jpg" ) ;			//	３：背景２

End() ;	//	初期化終了(Ver0.04以降はこれを記述してください)


//	[Start] ← ゲーム開始時に呼ばれるラベル
[Start]

//●●● タイトルの設定 ●●●●●●●●●●●●●●●

//	全スプライトを消す
//	DelSprite( スプライト番号, 消えるまでの時間 ) ;
//	SpriteNoに「_ALL」を指定すると、全てのスプライトを削除
DelSprite( _ALL, 0 ) ;

//	タイトル画面をスプライトとして表示
//	Sprite( スプライト番号, 画像番号, アラインモード, Ｘ, Ｙ, プライオリティ, 表示されるまでの時間 ) ;
//	アラインに「_ALIGN_CENTER」を指定すると、画面中央に表示
Sprite( 0, 1, _ALIGN_CENTER,  0,   0, _PRIO_NORMAL, 0 ) ;


//	背景設定
//	BackGround( 画像番号, スクロールX, スクロールY ) ;
BackGround( 2, 1, 1 ) ;

//	フェードインして画面表示
//	FadeIn( フォード時間 ) ;
FadeIn( 30 ) ;
Wait( 30 ) ;

//	キー入力待ち(クリックされるまでここで停止)
WaitKey( _INPUT_MOUSE ) ;

//	フェードアウトしてタイトル終了
FadeOut( 30 ) ;
Wait( 30 ) ;
DelSprite( _ALL, 0 ) ;


//●●● フェードインしてゲーム開始 ●●●●●●●●●
BackGround( 3, 0, 0 ) ;
FadeIn( 30 ) ;
Wait( 30 ) ;

//	メッセージウィンドウを開く
Wait( 30 ) ;
OpenWindow( _WIN_NOVEL ) ;

NovelFadeIn( 30 ) ;
Wait( 30 ) ;

//	メッセージ中の「@S」 ▼を表示して入力待ちします
//	　　　　　　　「@C」 表示されているメッセージを全て消します

//−−−−−−−−−−メッセージはここまで■
_M_START_
たんしおツクール（仮）の
サンプルプログラム・ノベル版です。@S
このサンプルは、サウンドノベルを
作る場合を想定したスクリプトです。@S
このモードでは、文字は横２２文字×縦１７文字
表示することができます。@S@C
_M_END_

//	テキストを消して背景を表示
NovelFadeOut( 30 ) ;
Wait( 30 ) ;

//	Sprite( スプライト番号, 画像番号, アラインモード, Ｘ, Ｙ, プライオリティ, 表示されるまでの時間 ) ;
Sprite( 1, 0, _ALIGN_BOTTOM, 200, 0, _PRIO_NORMAL, 30 ) ;
Wait( 30 ) ;

//	背景を暗くしてテキストを表示
NovelFadeIn( 30 ) ;
Wait( 30 ) ;

//−−−−−−−−−−メッセージはここまで■
_M_START_
次は、選択肢のサンプルです。
_M_END_

Select( "[Sel_1]その１", "[Sel_2]その２", "[Sel_3]その３" ) ;

//●●● 一番上を選んだ場合 ●●●●
[Sel_1]
_M_START_
その１を選びましたね。
_M_END_
Jump( "[End]" ) ;

//●●● ２番目を選んだ場合 ●●●●
[Sel_2]
_M_START_
その２を選びましたね。
_M_END_
Jump( "[End]" ) ;

//●●● ３番目を選んだ場合 ●●●●
[Sel_3]
_M_START_
その３を選びましたね。
_M_END_

//●●● 終了処理へ ●●●●●●●●●●●●●●●●●
[End]

//−−−−−−−−−−メッセージはここまで■
_M_START_
このサンプルはここでおしまいです。
プログラマ向けの「テキストエディタで
バリバリ書きたい！」人向けです。@S
アドベンチャー・クイズ・ノベル
という、テキスト系の内容で力を
発揮できるかと思います。@S
元々むりげー用にと思ったんですが、
あまりむりげー向きではないな！
と気付きましたｏｒｚ@S
_M_END_

//	メッセージウィンドウを閉じる
NovelFadeOut( 30 ) ;
Wait( 30 ) ;
CloseWindow( _WIN_NOVEL ) ;
DelSprite( 1, 30 ) ;
Wait( 30 ) ;

//--- フェードアウト ---------------------------------
FadeOut( 30 ) ;
Wait( 60 ) ;
DelSprite( _ALL, 0 ) ;

//--- タイトル画面に戻る -----------------------------
Jump( "[Start]" ) ;