//	たんしおスクリプト	Ver0.04版対応
//	2010/05/27

[Init]

//●●● ↓ここを設定してください↓ ●●●●●●●●●●●●●●●●●

//	タイトル（読み込み中に左上に表示されます）
String		strTitle = "クイズ！牛のきもち" ;

//	正解の時の効果音
String		strSoundOK = "image/ok.mp3" ;

//	間違いの時の効果音
String		strSoundNG = "image/ng.mp3" ;

//	タイトル画像
String		strImageTitle = "image/title.gif" ;

//	背景画像
String		strImageWallPaper = "image/wallpaper.gif" ;

//	クイズテキストのファイル名
String		strQuizFile = "image/quiz.txt" ;

//	このページのＵＲＬ（ツイッター書き込み用）
String		strURL = "http://www.tansio.net/create/sample/sample02/" ;

//	出題数
int			nQuizCount = 10 ;

//	制限時間（秒）
int			nTime = 10 ;

//●●● ↑ここを設定してください↑ ●●●●●●●●●●●●●●●●●

int			nSelect ;	//	選択肢の結果
int			nAns ;		//	答えられた数

int		SOUND_OK        = 0 ;
int		SOUND_NG        = 1 ;
int		IMAGE_TITLE     = 0 ;
int		IMAGE_WALLPAPER = 1 ;

SetTitle( strTitle ) ;
Quiz_Load( strQuizFile ) ;


//--- 読み込み ---------------------------------------

//		   ImageNo, FileName
LoadImage( IMAGE_TITLE,     strImageTitle ) ;		//	タイトル画面
LoadImage( IMAGE_WALLPAPER, strImageWallPaper ) ;	//	背景

LoadSound( SOUND_OK,    strSoundOK ) ;
LoadSound( SOUND_NG,    strSoundNG ) ;
SetSysParam( _SYS_QUIZ_SOUND_OK, SOUND_OK ) ;
SetSysParam( _SYS_QUIZ_SOUND_NG, SOUND_NG ) ;

End() ;	//	初期化終了(Ver0.04以降はこれを記述してください)


//	[Start] ← ゲーム開始時に呼ばれるラベル
[Start]

//●●● タイトルの設定 ●●●●●●●●●●●●●●●

//	全スプライトを消す
//	SpriteNo, Frame
//	SpriteNoに「_ALL」を指定すると、全てのスプライトを削除
DelSprite( _ALL, 0 ) ;

//	タイトル画面
//	SpriteNo, ImageNo, Align X, Y, Prio, Frame
Sprite( 0, IMAGE_TITLE, _ALIGN_CENTER,  0,   0, _PRIO_NORMAL, 0 ) ;

//	背景設定
//	ImageNo, ScrollX, ScrollY
BackGround( IMAGE_WALLPAPER, 1, 1 ) ;

//	フェードインして画面表示
//	Frame
FadeIn( 30 ) ;
Wait( 30 ) ;

//	キー入力待ち(クリックされるまでここで停止)
WaitKey( _INPUT_MOUSE ) ;

//	タイトル消える
DelSprite( 0, 30 ) ;

Wait( 30 ) ;

//	メッセージウィンドウを開く
OpenWindow( _WIN_MESSAGE ) ;

//	メッセージ中の「@S」 ▼を表示して入力待ちします
//	　　　　　　　「@C」 表示されているメッセージを全て消します

//        ０１２３４５６７８９０１２３４５６７８９

Message( "クイズを始めます。" ) ;
Message( "問題数は全部で" + Zenkaku( nQuizCount ) + "問。" ) ;
Message( "制限時間は１問当たり" + Zenkaku( nTime ) + "秒です。@S" ) ;

//	LV, Count, Frame, Miss, Flag
nAns = Quiz_Start( 0, nQuizCount, nTime * 30, 0, 0 ) ;

//        ０１２３４５６７８９０１２３４５６７８９
Message( "正解率は" + Zenkaku( nAns * 100 / nQuizCount ) + "％でした。@S" ) ;


//	ツイッター確認
Message( "@Cツイッターに書き込みますか？" ) ;
nSelect = Select( "はい、書き込みます", "いいえ、ツイッターしてません" ) ;
if( nSelect == 1 ) "[End]" ;	//	いいえの場合

//	ツイッター書き込み
Twitter( strTitle + "正解率：" + Zenkaku( nAns * 100 / nQuizCount ) + "％" + strURL ) ;
jump( "[End]" ) ;

[End]
CloseWindow( _WIN_MESSAGE ) ;
Wait( 30 ) ;

//--- フェードアウト ---------------------------------
FadeOut( 30 ) ;
Wait( 60 ) ;
DelSprite( _ALL, 0 ) ;

//--- タイトル画面に戻る -----------------------------
Jump( "[Start]" ) ;