//	たんしおスクリプト	Ver0.04版対応
//	2010/05/27
//	このスクリプトの仕様は大幅に変わる可能性があります！
//	使用される方は、仕様変更を覚悟してご利用ください！


//	[Init] ← 読み込み中に呼ばれるラベル
[Init]

SetTitle( "たんしおツクールサンプル" ) ;

//●●● 画像の読み込み ●●●●●●●●●●●●●●●
//	LoadImage( 画像番号, ファイル名 ) ;
LoadImage(  0, "image/takane.gif" ) ;		//	０：高嶺さんの画像
LoadImage(  1, "image/title.gif" ) ;		//	１：タイトル画面
LoadImage(  2, "image/wallpaper.png" ) ;	//	２：背景
LoadImage(  3, "image/akari.gif" ) ;		//	３：あかりの画像

End() ;	//	初期化終了(Ver0.04以降はこれを記述してください)


//	[Start] ← ゲーム開始時に呼ばれるラベル
[Start]

//●●● タイトルの設定 ●●●●●●●●●●●●●●●

//	全スプライトを消す
//	DelSprite( スプライト番号, 消えるまでの時間 ) ;
//	SpriteNoに「_ALL」を指定すると、全てのスプライトを削除
DelSprite( _ALL, 0 ) ;

//	タイトル画面をスプライトとして表示
//	Sprite( スプライト番号, 画像番号, アラインモード, Ｘ, Ｙ, プライオリティ, 表示されるまでの時間 ) ;
//	アラインに「_ALIGN_CENTER」を指定すると、画面中央に表示
Sprite( 0, 1, _ALIGN_CENTER,  0,   0, _PRIO_NORMAL, 0 ) ;


//	背景設定
//	BackGround( 画像番号, スクロールX, スクロールY ) ;
BackGround( 2, 1, 1 ) ;

//	フェードインして画面表示
//	FadeIn( フォード時間 ) ;
FadeIn( 30 ) ;
Wait( 30 ) ;

//	キー入力待ち(クリックされるまでここで停止)
WaitKey( _INPUT_MOUSE ) ;

//	フェードアウトしてタイトル終了
FadeOut( 30 ) ;
Wait( 30 ) ;
DelSprite( _ALL, 0 ) ;

//●●● フェードインしてゲーム開始 ●●●●●●●●●
FadeIn( 30 ) ;
Wait( 30 ) ;

//	メッセージウィンドウを開く
Wait( 30 ) ;
OpenWindow( _WIN_MESSAGE ) ;

//	メッセージ中の「@S」 ▼を表示して入力待ちします
//	　　　　　　　「@C」 表示されているメッセージを全て消します

//−−−−−−−−メッセージはここまで■
_M_START_
たんしおツクール（仮）の
サンプルプログラムです。@S
このサンプルは、アドベンチャーゲームを
作る場合を想定したスクリプトです。
まずは、スプライト表示から。@S@C
_M_END_

//	Sprite( スプライト番号, 画像番号, アラインモード, Ｘ, Ｙ, プライオリティ, 表示されるまでの時間 ) ;
Sprite( 1, 0, _ALIGN_BOTTOM, 200, 0, _PRIO_NORMAL, 30 ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
高嶺「萌え〜！@S@C
と、こんな感じでスプライトを表示する
ことができます。@S
_M_END_

//	Sprite( スプライト番号, 画像番号, アラインモード, Ｘ, Ｙ, プライオリティ, 表示されるまでの時間 ) ;
Sprite( 2, 3, _ALIGN_BOTTOM, 360, 0, _PRIO_NORMAL, 30 ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
もちろんいっぱい表示できます。@S@C
_M_END_

DelSprite( 1, 30 ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
高嶺「あべし〜！@S@C
次は、選択肢のサンプルです。
_M_END_

Select( "[Sel_1]その１", "[Sel_2]その２", "[Sel_3]その３" ) ;

//●●● 一番上を選んだ場合 ●●●●
[Sel_1]
_M_START_
その１を選びましたね。
_M_END_
Jump( "[End]" ) ;

//●●● ２番目を選んだ場合 ●●●●
[Sel_2]
_M_START_
その２を選びましたね。
_M_END_
Jump( "[End]" ) ;

//●●● ３番目を選んだ場合 ●●●●
[Sel_3]
_M_START_
その３を選びましたね。
_M_END_

//●●● 終了処理へ ●●●●●●●●●●●●●●●●●
[End]

//	あかり消す
DelSprite( 2, 30 ) ;

//−−−−−−−−メッセージはここまで■
_M_START_
このサンプルはここでおしまいです。
プログラマ向けの「テキストエディタで
バリバリ書きたい！」人向けです。@S
アドベンチャー・クイズ・ノベル（予定）
という、テキスト系の内容で力を
発揮できるかと思います。@S
元々むりげー用にと思ったんですが、
あまりむりげー向きではないな！
と気付きましたｏｒｚ@S
_M_END_

//	メッセージウィンドウを閉じる
CloseWindow( _WIN_MESSAGE ) ;

//--- フェードアウト ---------------------------------
FadeOut( 30 ) ;
Wait( 60 ) ;
DelSprite( _ALL, 0 ) ;

//--- タイトル画面に戻る -----------------------------
Jump( "[Start]" ) ;